Adding a Root Mover to KFRigs

Since older versions of my KF Rigs don't have a Root Mover, here's the process to add it yourself

1. Open the *_GameReady.ma version of the rig

2. Open the Script Editor

3. Go to a MEL tab in the Script Editor

4. Run the following MEL lines

////////////////////////////////////////////////////////
string $j = "Root";
    
curve -d 1 -p 0 0 -9 -p 2 0 -9 -p 1 0 -8 -p 8 0 -8 -p 8 0 -1 -p 9 0 -2 -p 9 0 2 -p 8 0 1 -p 8 0 8 -p 1 0 8 -p 2 0 9 -p -2 0 9 -p -1 0 8 -p -8 0 8 -p -8 0 1 -p -9 0 2 -p -9 0 -2 -p -8 0 -1 -p -8 0 -8 -p -1 0 -8 -p -2 0 -9 -p 0 0 -9 -k 0 -k 1 -k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 11 -k 12 -k 13 -k 14 -k 15 -k 16 -k 17 -k 18 -k 19 -k 20 -k 21 ;
rename "CTRL_Root_Mover";
string $ctrl[] = `ls -sl`;

group -em -n ($ctrl[0] + "Adjust");
string $ctrlGrp[] = `ls -sl`;

parent $ctrl $ctrlGrp;

setAttr -lock true -keyable false -channelBox false ($ctrl[0] + ".sx");
setAttr -lock true -keyable false -channelBox false ($ctrl[0] + ".sy");
setAttr -lock true -keyable false -channelBox false ($ctrl[0] + ".sz");
setAttr -lock true -keyable false -channelBox false ($ctrl[0] + ".v");

string $track[] = `ls ("CTRL_*_TrackerAdjust")`;

if(`size($track)` > 0)
{parent $ctrlGrp $track;}
else
{parent $ctrlGrp DO_NOT_ADJUST;}

string $con[] = `parentConstraint -mo $ctrl $j`;
select $con;
rename ($con[0] + "_UNtoDEL");

addAttr -ln "rootMoverVis" -at long  -min 0 -max 1 -dv 0 CTRL_Vis;
setAttr -e -keyable true CTRL_Vis.rootMoverVis;
setAttr -keyable false -channelBox true "CTRL_Vis.rootMoverVis";

connectAttr -f "CTRL_Vis.rootMoverVis" ($ctrlGrp[0] + ".v");

string $objShapes[] = `listRelatives -shapes $ctrl[0]`;
setAttr ($objShapes[0] + ".overrideEnabled") 1;
setAttr ($objShapes[0] + ".overrideColor") 18;


select -cl;
//////////////////////////////

5. Save the file

Do let me know if this helps